root/trunk/t/c/holder-move.t

use strict;
use warnings;

use Test::More tests => 45;

require 't/helpers.pl';

use_ok('Scrpbk::C::Holder');
use Scrpbk::M::Person;
use Scrpbk::M::Holder;
use Data::Dumper;

ok my $mech      = get_mech(),  "set up the Test::WWW::Mechanize object";
ok my $test_user = test_user(), "get test user";

# delete if there are pages found.
for ( grep { $_->url =~ m/^[abc]$/ } $test_user->pages ) {
    fail "found page that should not have been here:" . $_->url;
    $_->delete;
}

# Log in as test user.
ok login_as_test(), "login as test user";

################################################################################
# Create a few holders on several pages.
foreach my $page_ref (qw/a b c/) {
    ok my $page =
      $test_user->add_to_pages(
        { url => $page_ref, name => "Page $page_ref" } ),
      "Create page '$page_ref'";

    foreach my $column ( 1 .. 2 ) {
        foreach my $rank ( 1 .. 3 ) {
            my $holder_name = "$page_ref-$column-$rank";
            ok my $holder = $test_user->add_to_holders(
                {
                    page => $page,
                    col  => $column,
                    rank => $rank,
                    name => $holder_name
                }
              ),
              "  Create holder with name: '$holder_name'";
        }
    }
}

################################################################################
# Do a few moves and then check that the col and rank are correct.

# Go to page 'a'
$mech->follow_link_ok( { url => '/~' . $test_user->tag }, "go to users page" );
$mech->follow_link_ok( { url_regex => qr/page\/a/ }, "go to page 'a'" );

# Check that the rank is correct.
ok holder('a-1-1')->rank < holder('a-1-2')->rank, "a11s rank is less than a12";
ok holder('a-1-2')->rank < holder('a-1-3')->rank, "a12s rank is less than a13";

{    # 'a-1-2' -> move down.
    $mech->form('page_edit');
    $mech->click( 'act_moveholder_' . holder('a-1-2') . '_down' );
    ok holder('a-1-2')->rank > holder('a-1-3')->rank,
      "a12s rank is greater than a13";
}

{    # 'a-1-2' -> move up.
    $mech->form('page_edit');
    $mech->click( 'act_moveholder_' . holder('a-1-2') . '_up' );
    ok holder('a-1-2')->rank < holder('a-1-3')->rank,
      "a12s rank is less than a13";
}

{    # 'a-1-2' -> move right
    $mech->form('page_edit');
    $mech->click( 'act_moveholder_' . holder('a-1-2') . '_right' );
    ok holder('a-1-2')->col == 2, "check that 'a-1-2' is now in col 2";
    ok holder('a-1-2')->rank < holder('a-2-1')->rank,
      "a12s rank is less than a21";
}

{    # 'a-2-3' -> move left
    $mech->form('page_edit');
    $mech->click( 'act_moveholder_' . holder('a-2-3') . '_left' );
    ok holder('a-2-3')->col == 1, "check that 'a-2-3' is now in col 1";
    ok holder('a-2-3')->rank < holder('a-1-1')->rank,
      "a23s rank is less than a11";
}

################################################################################
# Move holders between pages.

# Go to page b
$mech->follow_link_ok( { url_regex => qr/page\/b/ }, "go to page 'b'" );

{    # Go to edit page for holder b22.
    my $id = holder('b-2-2')->id;
    $mech->follow_link_ok( { url_regex => qr/edit\/$id/ },
        "edit holder 'a22'" );

    # On the form change the page value to 'c';
    ok $mech->submit_form(
        form_name => 'edit_holder',
        fields    => { page => 'Page c' }
      ),
      "submit form";

    # Check that we have come through to page c.
    like $mech->uri, qr/page\/c$/, "check that we are now on page c";

    # Check that the holder has changed correctly.
    is holder('b-2-2')->page->url, 'c', "Check on right page";
    is holder('b-2-2')->col, '1', "in correct column";
    ok holder('b-2-2')->rank < holder('c-1-1')->rank, "first on list";
}

################################################################################
# delete all pages created.
ok $_->delete, "delete page"
  for grep { $_->url =~ m/^[abc]$/ } $test_user->pages;

################################################################################